home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / pc / LOGIC Apple II 5.25" Library - DOS Part 3 / DOS078A.dsk / THERMOSYPHON.bas < prev    next >
BASIC Source File  |  2012-02-16  |  3KB  |  40 lines
  1. 4  REM  =======================
  2. 5  REM  THERMOSYPHON EQUATIONS
  3. 6  REM  BY M.WIDMANN JAN 1982
  4. 7  REM  =======================
  5. 9  GOSUB 600: CALL  -936: DIM I(10),A$(10)
  6. 10 I(1) = .04:I(2) = .03:I(3) = 35:I(4) = 17:I(5) = .05:I(6) = .075:I(7) = 290:I(8) = 2.1:I(9) = 166:I(10) = .84
  7. 11  GOSUB 800
  8. 13  PRINT : PRINT : INPUT "   ANY CHANGES(Y/N)?";N$: IF N$ = "N"  THEN 20
  9. 14  GOSUB 800: PRINT : PRINT : INPUT "    WHICH VARIABLE?";N: IF N <1  OR N >10  THEN 14
  10. 15  PRINT : INPUT "    ENTER VALUE:";I(N): GOTO 11
  11. 20 LL = I(1):LG = I(2):EL = I(3):EG = I(4):DL = I(5):DG = I(6):C = I(7):AL = I(8)
  12. 110 X = 1: GOSUB 1000:M(1) = B(2) -A(2):M(2) = A(1) +A(3) +B(1) +B(3):X = (M(1)/M(2)) ^.5
  13. 200  CALL  -936: INVERSE : VTAB 5: FOR S = 1 TO 40: PRINT "=";: NEXT : NORMAL : VTAB 7: PRINT "MAX.FLOWRATE:";: HTAB 24: PRINT X;" G/SEC"
  14. 210  HTAB 24: PRINT .888 *X;"GAL/HR": PRINT 
  15. 215  GOSUB 1000
  16. 220  INVERSE : PRINT "===========PRESSUREDROPS (PSI)==========": NORMAL : PRINT : PRINT "FRICT.GAS:";.015 *A(1): PRINT "STATC.GAS:";.015 *A(2): PRINT "FRICT.LQU:";.015 *B(1): PRINT "STATC.LQU:";.015 *B(2)
  17. 300  PRINT : INPUT "    CONTINUE(Y/N)?";N$: IF N$ = "Y"  THEN 11
  18. 310  PRINT : PRINT : PRINT "******* BYE *********
  19. 320  END 
  20. 600  TEXT : HOME : VTAB 5: HTAB 15: PRINT "THERMOSYPHON": PRINT 
  21. 610  PRINT "THIS PROGRAM IS A SIMULATION OF REFLUX": PRINT "IN A CLOSED SYSTEM. IT CALCULATES THE": PRINT "MASS TRANSFER IN GRAM/HR OF MATERIAL OR": PRINT "GAL/HR OF CONDENSATE."
  22. 620  PRINT "CIRCULATION IS SOLELY BASED ON THERMAL": PRINT "FORCE AND NO PUMPS ETC ARE INCLUDED": PRINT : PRINT "THE EXAMPLE CONSTANTS ARE FOR A DOW-": PRINT "THERM SYSTEM (MW=166, SPEC.GRAV.=.84)": PRINT "USING AVG FRICTION FACTORS FOR PIPES."
  23. 630  PRINT "EQUIVALENT LENGTHS OF PIPES DENOTES": PRINT "ACTUAL LENGTH PLUS EQUIVALENT LENGTHS": PRINT "FOR ELLBOWS, VALVES, ETC.": PRINT : PRINT "ALL UNITS ARE IN METERS"
  24. 640  PRINT : INPUT "PRESS RETURN TO CONT.>>";N$: RETURN 
  25. 800  RESTORE : CALL  -936: PRINT 
  26. 810  PRINT : FOR N = 1 TO 10: READ A$(N): PRINT " ";N;"  ";A$(N);: HTAB 28: PRINT I(N): NEXT : RETURN 
  27. 900  DATA   FRICTIONFACTOR LIQ,FRICTIONFACTOR GAS,EQU LENGTH LIQ,EQU LENGTH GAS,DIAM LIQU,DIAM GAS,TEMP,ELEVATION,MOL WEIGHT,SPEC GRAVITY
  28. 1000  REM  GASLINE FRICTION LOSS
  29. 1010 A(1) = 6.701E -10 *LG *EG/DG ^5 *X ^2 *(273 +C) *1/I(9)
  30. 1015  REM GASLINE STATIC LOSS
  31. 1020 A(2) = 1.229 *AL *1/(273 +C) *I(9)
  32. 1025  REM  LIQUID FRICTION LOSS
  33. 1030 B(1) = 8.108E -12 *LL *EL/DL ^5 *X ^2 *1/I(10)
  34. 1035  REM  LIQUID STATIC LOSS
  35. 1040 B(2) = 100 *AL *I(10)
  36. 1045  REM  GAS KINETIC
  37. 1050 A(3) = 6.65E -9 *X ^2 *(273 +C)/I(9)/DG ^4
  38. 1055  REM LIQUID KINETIC
  39. 1060 B(3) = 8.06E -11 *X ^2/DL ^4/I(10)
  40. 1061  RETURN